가상 노드와 가상 관계

아직 노출되지 않은 테이블 erp.po_line(발주 품목)을 가상 노드로 만들고, 발주·품목과 관계로 이어 봅니다. 다른 데이터베이스의 테이블이 한 그래프로 이어지는 순간을 직접 만듭니다.

가상 노드란#

가상 노드 타입은 원천 테이블 하나를 그래프의 노드 라벨 하나로 비춘 것입니다.

• 원천 행 하나 = 노드 하나, 컬럼 = 속성입니다.
• KEY 컬럼이 노드를 구별하는 값입니다(보통 기본키).
• 데이터는 복사되지 않습니다. MATCH (n:PoLine)을 실행할 때마다 원천 erp.po_line을 읽습니다.
• 읽기 전용입니다. 가상 노드에 CREATE나 SET을 하면 엔진이 거절합니다. 값을 바꾸려면 원천 시스템에서 바꿔야 하고, Ontological Studio에서는 그 일을 액션이 합니다(6부).

따라 하기 — 발주 품목을 노드로#

1. 데이터소스 탭에서 erp를 고르고, 테이블 목록에서 po_line을 누릅니다. 아직 「노출 안 됨」입니다.
2. 오른쪽 아래 가상 노드로 노출 상자에서 노드 타입 이름을 PoLine, 그래프를 sample, KEY 컬럼을 po_line_id로 둡니다.
3. 속성은 그대로 두면 모든 컬럼이 같은 이름의 속성이 됩니다. 이름을 바꾸고 싶으면 오른쪽 칸을 고칩니다(예: qty → quantity).
4. 「실행될 문장」을 확인하고 「가상 노드 만들기」를 누릅니다.

실행되는 문장은 이것입니다.

CREATE VIRTUAL NODE PoLine IN sample FROM erp.po_line KEY po_line_id

속성 이름을 바꾸면 PROPERTIES (po_line_id, po_id, item_id, qty AS quantity)처럼 붙습니다. 만들자마자 미리보기에 원천의 9행이 나옵니다.

가상 그래프 보기#

왼쪽 아래 가상 그래프에서 sample을 누르면, 데이터소스별로 묶인 노드와 관계의 지도가 나옵니다. PoLine은 아직 아무와도 이어져 있지 않습니다.

따라 하기 — 관계로 잇기#

발주 품목은 “어느 발주의” 줄이고 “어느 품목”을 산 것입니다. 이 두 사실을 관계로 만듭니다.

1. 가상 그래프 화면 아래 관계 만들기 칸에 관계 이름 IN_ORDER를 적습니다.
2. 출발 노드 PoLine, 속성 po_id → 도착 노드 PurchaseOrder, 속성 po_id를 고릅니다.
3. 「관계 만들기」를 누릅니다.

CREATE VIRTUAL RELATIONSHIP IN_ORDER IN sample FROM PoLine(po_id) TO PurchaseOrder(po_id)

같은 방법으로 품목과도 잇습니다. 이번에는 포털에서 직접 문장을 쳐 봅시다(포털은 7장에서 자세히 다룹니다. 그래프 선택을 sample로 두세요).

CREATE VIRTUAL RELATIONSHIP OF_ITEM IN sample FROM PoLine(item_id) TO Item(item_id)

관계도 복사가 아닙니다. 조인 규칙(PoLine.po_id = PurchaseOrder.po_id)을 이름 붙여 저장해 둔 것이고, 질의할 때 그 규칙대로 원천을 조인합니다.

바로 써 보기#

이제 “협력사별로 어떤 품목을 몇 개나 발주했나”를 묻는 질의를 쓸 수 있습니다. 협력사 → 발주 → 발주 품목 → 품목으로 네 노드를 걸어갑니다.

MATCH (s:Supplier)<-[:ORDERED_FROM]-(po:PurchaseOrder)<-[:IN_ORDER]-(l:PoLine)-[:OF_ITEM]->(i:Item)
RETURN s.name, i.name, sum(l.qty) AS qty
ORDER BY s.name, i.name

그리고 이번에는 세 시스템을 건너는 질문입니다. “3일 넘게 늦은 선적이 싣고 오는 품목과 그 안전재고는?” — 선적은 WMS에, 발주·발주 품목·품목은 ERP에 있습니다.

MATCH (i:Item)<-[:OF_ITEM]-(l:PoLine)-[:IN_ORDER]->(po:PurchaseOrder)<-[:SHIPS]-(sh:Shipment)
WHERE sh.delay_days > 3
RETURN DISTINCT i.name, i.safety_stock, sh.shipment_no, sh.delay_days

두 선적 모두 PCB 기판을 싣고 오고 있습니다. 재고 담당자에게 먼저 알려야 할 품목이 나왔습니다.

만든 것을 지우려면#

DROP VIRTUAL RELATIONSHIP OF_ITEM IN sample
DROP VIRTUAL RELATIONSHIP IN_ORDER IN sample
DROP VIRTUAL NODE PoLine IN sample

관계가 이어져 있는 노드는 지울 수 없습니다. 엔진이 virtual relationships still join on 'PoLine' (IN_ORDER, OF_ITEM); drop them first라며 거절하고, 데이터소스 탭은 이 이유를 한국어로 바꿔 보여 줍니다. 관계부터 지우세요. 원천 테이블은 아무 영향을 받지 않습니다.

MATCH (s:Supplier)<-[:ORDERED_FROM]-(po:PurchaseOrder)<-[:IN_ORDER]-(l:PoLine)-[:OF_ITEM]->(i:Item)
WHERE po.status = 'OPEN'
RETURN s.name, i.name, sum(l.qty) AS qty ORDER BY s.name, i.name